<?xml version="1.0"?>
<!-- tested with build-in processor in XMLSpy 2007 and with Saxon8b in Oxygen -->
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:strip-space elements="*"/>
	<xsl:output method="text"/>
	<xsl:template match="products/product">
		<!--variables normalized input-->
		<xsl:variable name="idN" select="normalize-space(@id)"/>
		<xsl:variable name="nameN" select="normalize-space(name)"/>
		<xsl:variable name="priceN" select="normalize-space(price)"/>
		<xsl:variable name="stockN" select="normalize-space(stock)"/>
		<xsl:variable name="countryN" select="normalize-space(country)"/>
		<!--variables extra spaces-->
		<xsl:variable name="idSpace" select="for $a in 1 to (3 - string-length($idN)) return ' '"/>
		<xsl:variable name="nameSpace"
			select="for $a in 1 to (8 - string-length($nameN)) return ' '"/>
		<xsl:variable name="priceSpace"
			select="for $a in 1 to (10 - string-length($priceN)) return ' '"/>
		<xsl:variable name="stockSpace"
			select="for $a in 1 to (3 - string-length($stockN)) return ' '"/>
		<xsl:variable name="countrySpace"
			select="for $a in 1 to (10 - string-length($countryN)) return ' '"/>
		<!--fixed output begins here-->
		<xsl:value-of select="concat($idN, string-join($idSpace, ''))"/>
		<xsl:value-of select="concat(string-join($nameSpace, ''), $nameN)"/>
		<xsl:value-of select="concat(string-join($priceSpace, ''), $priceN)"/>
		<xsl:value-of select="concat(string-join($stockSpace, ''), $stockN)"/>
		<xsl:value-of select="concat(string-join($countrySpace, ''), $countryN)"/>
		<xsl:text>&#xA;</xsl:text>
	</xsl:template>
	<!-- Version 2.b -->
	<!-- 1) We now also normalize space in input data (numbers are alwas normalized). -->
	<!-- 2) We have removed the xsl:for-each since the template itself is enough. -->
	<!-- 3) XMLSpy's built in processor is stripping whitespace-only text-nodes. Xsl:strip-space is not needed. -->
	<!-- 4) In Saxon we must include xsl:strip-space or delete the linefeed at the end of last template. -->
	<!-- 5) The solution above works in both Saxon and in XMLspy's build-in processor. -->
</xsl:stylesheet>
